윈도우 패키지 매니저 Chocolatey
컴퓨터를 포맷한 후 초기 설정할 때 유용하게 사용중인 프로그램이다.
여태 프로그램을 설치하기 위해선 프로그램을 검색한 후, 사이트에 들어가서 설치 파일을 다운받은 후, 설치 파일을 실행시켜 일일히 Next를 눌러 가며 설치해야 했다.
Chocolatey를 사용하면 이 과정을 choco install python -y 와 같이 명령어 한 줄로 설치할 수 있다.
미리 설치 명령어가 담긴 배치 파일을 만들어 둔다면, 포맷 후 한번에 모든 프로그램을 설치할 수 있다.
choco upgrade all 명령어를 사용하면 모든 프로그램을 업데이트할 수 있다.
설치 방법
공식 홈페이지에서 설치 커맨드를 복사한다.
윈도우 + X 키 를 눌러 Windows 터미널(Windows PowerShell)을 관리자 모드로 열어준 후, 복사한 커맨드를 붙여넣기한 후 엔터를 눌러주면 설치가 진행된다.
사용 방법
여기서 설치하고 싶은 패키지를 검색한다.
커맨드를 복사한 후, Windows PowerShell에서 커맨드를 실행한다. 조금만 기다리면 패키지가 설치된다.
커맨드
패키지 검색
choco search 패키지명
패키지 설치
choco install 패키지명
패키지 설치 (프롬프트/버전 포함)
choco install -y 패키지명 --version 버전
설치된 패키지 버전 업그레이드
choco upgrade 패키지명
패키지 상세 정보
choco info 패키지명
설치된 패키지 확인
choco list -l
설치된 패키지 삭제
choco uninstall 패키지명
chocolatey 버전 업그레이드
choco upgrade chocolatey
Chocolatey와 패키지를 한번에 설치하는 스크립트
아래 소스 코드는 본 작성자가 사용하고 있는 스크립트인데, 아래 주석 부분을 수정해서 사용하면 된다.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
| @echo off
CLS
ECHO **************************************
ECHO * Start Chocolatey Batch
ECHO **************************************
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )
:getPrivileges
if '%1'=='ELEV' (shift & goto gotPrivileges)
ECHO.
ECHO **************************************
ECHO * Use UAC, switch to admin
ECHO **************************************
setlocal DisableDelayedExpansion
set "batchPath=%~0"
setlocal EnableDelayedExpansion
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\OEgetPrivileges.vbs"
ECHO UAC.ShellExecute "!batchPath!", "ELEV", "", "runas", 1 >> "%temp%\OEgetPrivileges.vbs"
"%temp%\OEgetPrivileges.vbs"
exit /B
:gotPrivileges
setlocal & pushd .
WHERE choco 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto chocoInstalled ) else ( goto chocoMissing )
:chocoMissing
ECHO.
choice /M "Chocolatey not found. Install now?"
IF '%errorlevel%' == '2' exit /B
ECHO.
ECHO **************************************
ECHO * Chocolatey install
ECHO **************************************
@powershell -NoProfile -ExecutionPolicy Bypass -Command "iex ((new-object net.webclient).DownloadString('https://chocolatey.org/install.ps1'))" && SET PATH=%PATH%;%ALLUSERSPROFILE%\chocolatey\bin
:chocoInstalled
ECHO.
ECHO **************************************
ECHO * Packages install
ECHO **************************************
@echo on
choco feature enable --name=allowGlobalConfirmation
choco upgrade all -y
:::::::::::::::::::::::: 이 부분을 변경하세요 ::::::::::::::::::::::::
:: 설치할 어플리케이션 목록
set choco_install=choco install -fy
%choco_install% bandizip
%choco_install% potplayer
%choco_install% everything
%choco_install% discord
%choco_install% leagueoflegends
%choco_install% steam
%choco_install% notion
%choco_install% zoom
%choco_install% webex
%choco_install% github-desktop
%choco_install% jetbrainstoolbox
%choco_install% vscode
%choco_install% visualstudio2022community
%choco_install% qbittorrent
%choco_install% obs-studio
:: chocolatey에 없는 프로그램들 다운로드 링크 링크 열기
start explorer https://creativecloud.adobe.com/apps/download/creative-cloud?locale=ko#
start explorer https://app-pc.kakaocdn.net/talk/win32/KakaoTalk_Setup.exe
start explorer https://www.onstove.com/download
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
choco feature disable --name=allowGlobalConfirmation
RefreshEnv.cmd
pause
|
